Native InstrumentsのKontaktのスクリプト言語であるKSPを、プログラミング未経験のミュージシャンでも理解できるように（心がけて）解説するブログ。今のところ、Kontakt4を対象にしています。誤字脱字や記載ミスなどがあったらゴメンナサイ。
もし、内容が難しくて理解出来ない場合には、Cプログラミング入門以前
set_event_parは、イベントのパラメータを設定するだけです。第1引数にはIDを、第2引数にはパラメータの種類を、第3引数には値を指定します。
on note
set_event_par($EVENT_ID,$EVENT_PAR_NOTE,30)
end on
何を弾いても、ノートナンバー30の音が再生されます。
set_event_par_arrは、第1引数にはIDを、第2引数は$EVENT_PAR_ALLOW_GROUPで固定、第3引数には1でグループを有効に0で無効に、第4引数にはグループインデックスを指定します。
on note
disallow_group($ALL_GROUPS)
set_event_par_arr($EVENT_ID,$EVENT_PAR_ALLOW_GROUP,1,find_group("Single"))
end on
この場合は、Singleというグループだけを有効にしています。
get_event_idsは、現在、有効なイベントがあれば、そのIDを配列に入れていきます。get_event_idsは、呼び出される度に配列の内容を上書きします。
on init
declare %Array[200]
end on
on note
get_event_ids(%Array)
message(%Array[0])
end on
これは、現在有効なイベントの1つ目のIDをステータスラインに表示します。
get_event_parは、第1引数にはイベントのIDを、第2引数には取り出すパラメータの種類を指定して、その値を取り出します。
on note
message(get_event_par($EVENT_ID,$EVENT_PAR_VELOCITY))
end on
この場合は、ノートオンのベロシティがステータスラインに表示されます。
get_event_par_arrは、指定したグループが有効か無効かの状態を返します。第1引数にはイベントのIDを、第2引数は$EVENT_PAR_ALLOW_GROUPで固定、第3引数にはグループインデックスを指定します。
on init
declare $State
end on
on note
disallow_group($ALL_GROUPS)
$State := get_event_par_arr($EVENT_ID,$EVENT_PAR_ALLOW_GROUP,find_group("Single"))
message($State)
end on
この場合は、Singleというグループが無効になっているので、0がステータスラインに表示されます。
on init
declare $State
end on
on note
$State := get_event_par_arr($EVENT_ID,$EVENT_PAR_ALLOW_GROUP,find_group("Single"))
message($State)
end on
このようにすると、1がステータスラインに表示されます。
ignore_eventは、指定したイベントのIDのノートイベントを無視しちゃいます。
on note
ignore_event($EVENT_ID)
end on
どの鍵盤を押しても、反応がなくなります。
ignore_controllerは、コントローラーイベントを無視しちゃいます。
on controller
if($CC_NUM = $VCC_PITCH_BEND)
ignore_controller
end if
end on
ピッチベンドを無効化しています。
event_statusはイベントIDを渡すと、そのイベントが生きているか死んでいるかを返します。生きていれば1、死んでいれば0を返します。
on init
declare $text
declare $id
end on
on note
$text := event_status($id)
message($text)
$id := $EVENT_ID
end on
1つ前のイベントのIDを渡してみると、0が返っていることが分かります。
on init
declare $text
declare $id
end on
on note
$id := $EVENT_ID
$text := event_status($id)
message($text)
end on
現在のイベントのIDを渡してみると、1が返っていることが分かります。
change_noteは、指定したイベントのノートナンバーを変更します。第1引数にはイベントのIDを、第2引数にはノートナンバーを指定します。
on init
declare ui_knob $Key(-12,12,1)
$Key := 0
end on
on note
change_note($EVENT_ID,$EVENT_NOTE+$Key)
end on
この場合は、ノブで指定した値だけキーを変更します。
change_panは、指定したイベントのパンを変更します。第1引数にはイベントのIDを、第2引数にはパンの値を、第3引数には第2引数の値が相対的か絶対的なのかを指定します。
on init
declare $Pan
end on
on note
$Pan := random(-1000,1000)
change_pan($EVENT_ID,$Pan,0)
end on
パンをランダムな値にしています。
change_tuneは、ミリセント単位で音程を変更します。第1引数にはイベントのIDを、第2引数には変更する値を、第3引数には第2引数の値が相対的か絶対的なのかを指定します。
on init
declare $tune
end on
on note
$tune := random(-500000,500000)
change_tune ($EVENT_ID,$tune,0)
end on
これを実行して鍵盤を連打すると、昔懐かしいアニメのコンピュータっぽい効果音になります（笑）
change_volもchange_veloも同じように使います。
on init
declare $note
declare $pan
declare $tune
declare $velo
end on
on note
$note := random(-12,12)
change_note($EVENT_ID,$EVENT_NOTE+$note)
$pan := random(-1000,1000)
change_pan($EVENT_ID,$pan,0)
$velo := random(-20,20)
change_velo($EVENT_ID,$velo)
$tune := random(-500000,500000)
change_tune ($EVENT_ID,$tune,0)
end on
全部ランダムにしてみると、こんな感じになります。
play_noteは、ノート・オンを生成します。第1引数にはノートナンバーを、第2引数にはベロシティを、第3引数にはオフセットを、第4引数にはデュレーションを指定します。第4引数には、-1を指定するとトリガーしたノートのノートオフと同時に音が止まります。0を指定すると、トリガーしたノートのノートオフに関係なく、サンプルの最後まで再生されます。
on note
play_note($EVENT_NOTE + 7,$EVENT_VELOCITY,0,-1)
end on
完全5度音程で、和音を生成します。
on note
while($NOTE_HELD = 1)
wait($DURATION_EIGHTH)
play_note($EVENT_NOTE + 7,$EVENT_VELOCITY,0,$DURATION_EIGHTH)
end while
end on
鍵盤が押されている間、8分音符感覚で、完全5度音程の音が再生されます。
note_offは、ノートオフを生成します。
on init
declare ui_button $Button
set_text ($Button,"Stop All Notes")
end on
on ui_control($Button)
note_off($ALL_EVENTS)
wait(100000)
$Button := 0
end on
発音中の全てのノートを停止させます。何かのエラーが起きた時のために、こういうボタンを用意しておくと親切かもしれません。
set_controllerは、CCやピッチベンドを生成します。第1引数にはCCナンバーか$VCC_PITCH_BENDでピッチベンドを指定します。第2引数には値を指定します。
on note
set_controller(1,100)
end on
on release
set_controller(1,0)
end on
ノートオンでモジュレーションが100、ノートオフでモジュレーションが0になります。
on init
declare @String
@String := output_channel_name(0)
message(@String)
end on
output_channel_name(0)の0を1や2にしてみると動作が分かると思います。
on init
declare ui_knob $Value (0,16383,1)
end on
on ui_control ($Value)
message("MSB: " & msb($Value) & " - LSB: " & lsb($Value))
end on
ui_knobに、14ビット分の値を設定します。で、msbで上位７ビット、lsbで下位7ビットの値を取り出しているわけです。この7ビットというのは、0~127を表現できるビット数のことですよ、と言うと、割と馴染みのある数字に見えてくると思います。
on init
message($KSP_TIMER)
end on
on note
message($KSP_TIMER)
end on
on controller
if($CC_NUM = 1)
reset_ksp_timer
message($KSP_TIMER)
end if
end on
waitは、指定した時間だけ、マイクロ秒単位でコールバックの処理を停止させます。
on note
wait($DURATION_EIGHTH)
play_note($EVENT_NOTE,$EVENT_VELOCITY,0,$DURATION_EIGHTH)
end on
8分音符分の時間だけ待って、リピートしてます。$DURATION_EIGHTHっていうのは組み込み変数で、現在のテンポでの8分音符分の時間になります。ちなみに、ticks_to_msはティックからマイクロ秒へ、ms_to_ticksは、マイクロ秒からティックへ変換します。
on init
declare $Ticks
$Ticks := ms_to_ticks($DURATION_QUARTER)
message($Ticks)
end on
on init
declare $test
declare $abs
$test := -2
$abs := abs($test)
message($abs)
end on
ステータスラインに2が表示されてますよね？
on init
declare $random
$random := random(0,10)
message($random)
end on
randomは第1引数には最小値を、第2引数には最大値を指定します。あとはその範囲内でステータスラインに値が表示されます。
on init
declare $inc
$inc := 3
inc($inc)
message($inc)
end on
ステータスラインに4が表示されてますよね。インクリメントは値を+1します。
on init
declare $dec
$dec := 3
dec($dec)
message($dec)
end on
デクリメントはその逆。
on init
declare $test
$test := 20
end on
on note
if($EVENT_NOTE = 64)
exit
else
inc($test)
message($test)
end if
end on
exitは、コールバックを強制終了します。ノートナンバー64（E）の時だけ、インクリメントされません。
on init
set_listener ($NI_SIGNAL_TRANSP_START,1)
set_listener ($NI_SIGNAL_TRANSP_STOP,1)
set_listener ($NI_SIGNAL_TIMER_MS,1000)
set_listener ($NI_SIGNAL_TIMER_BEAT,1)
end on
on listener
select ($NI_SIGNAL_TYPE)
case $NI_SIGNAL_TRANSP_STOP
message ("Stopped")
case $NI_SIGNAL_TRANSP_START
message ("Started")
case $NI_SIGNAL_TIMER_MS
case $NI_SIGNAL_TIMER_BEAT
end select
end on
set_listenerは、init callback内でのみ使えます。これで、どのタイミングでlistener callbackを呼び出すかを指定しておきます。第1引数にはシグナルタイプを、第2引数にはパラメータを指定します。シグナルタイプには四種類しかないので、覚えてしまいましょう。$NI_SIGNAL_TRANSP_STARTは、ホストがスタートした時で、$NI_SIGNAL_TRANSP_STOPは、ホストがストップした時にlistener callbackを呼び出すかを指定します。この場合は、第2引数のパラメータが1の時には、呼び出し、0の時には呼び出しません。注目すべきは、listener callbackで、select文で$NI_SIGNAL_TYPEによって、処理を選択出来ることです。これで、アイディア次第で色んな事ができます。$NI_SIGNAL_TIMER_MSは、第2引数に指定したマイクロ秒単位でlistener callbackを呼び出します。
on init
declare $Count
set_listener ($NI_SIGNAL_TRANSP_STOP,1)
set_listener ($NI_SIGNAL_TRANSP_START,1)
set_listener ($NI_SIGNAL_TIMER_MS,1000000)
set_listener ($NI_SIGNAL_TIMER_BEAT,1)
end on
on listener
select ($NI_SIGNAL_TYPE)
case $NI_SIGNAL_TRANSP_STOP
message ("Playback was stopped.")
case $NI_SIGNAL_TRANSP_START
message ("Playback was started.")
case $NI_SIGNAL_TIMER_MS
$Count := $Count + 1
message($Count)
case $NI_SIGNAL_TIMER_BEAT
end select
end on
1秒単位でlistener callbackを呼び出して、変数Countの値をステータスラインに表示しています。
on init
declare $Count
set_listener ($NI_SIGNAL_TRANSP_STOP,1)
set_listener ($NI_SIGNAL_TRANSP_START,1)
set_listener ($NI_SIGNAL_TIMER_MS,1000000)
set_listener ($NI_SIGNAL_TIMER_BEAT,1)
end on
on listener
select ($NI_SIGNAL_TYPE)
case $NI_SIGNAL_TRANSP_STOP
message ("Playback was stopped.")
case $NI_SIGNAL_TRANSP_START
message ("Playback was started.")
case $NI_SIGNAL_TIMER_MS
case $NI_SIGNAL_TIMER_BEAT
$Count := $Count + 1
message($Count)
end select
end on
$NI_SIGNAL_TIMER_BEATは、第2引数に、一拍あたりに何回呼び出すかをを指定します。
on init
declare $Count
set_listener ($NI_SIGNAL_TRANSP_STOP,1)
set_listener ($NI_SIGNAL_TRANSP_START,1)
set_listener ($NI_SIGNAL_TIMER_MS,1000000)
set_listener ($NI_SIGNAL_TIMER_BEAT,1)
change_listener_par($NI_SIGNAL_TIMER_BEAT,2)
end on
on listener
select ($NI_SIGNAL_TYPE)
case $NI_SIGNAL_TRANSP_STOP
message ("Playback was stopped.")
case $NI_SIGNAL_TRANSP_START
message ("Playback was started.")
case $NI_SIGNAL_TIMER_MS
case $NI_SIGNAL_TIMER_BEAT
$Count := $Count + 1
message($Count)
end select
end on
ちなみに、change_listener_parは、設定を変更するだけです。change_listener_parは、set_listenerと違い、どのコールバックでも使うことが出来ます。
set_control_parとget_control_parは、少し使いこなすのが難しいと思います。というのも、UI要素の各パラメータは、予め組み込み変数として用意されています。で、その変数にset_control_parによって値を設定したり、get_control_parによって値を取り出したりするわけです。なので、組み込み変数とセットで使い方を覚えないといけません。ですが、ここで組み込み変数の全てを一気に説明するのは大変なので、気になる人は、KSPのマニュアル（Kontakt4のです)で、114ページを見てください。
set_control_parの第1引数にはui要素のIDを、第2引数には組み込み変数を、第3引数には値を設定します。第3引数がテキストだったり配列だったりする場合には、それぞれ、set _control_par_strとset_control_par_arrに変わるところに注意が必要です。get_control_parは、第1引数にはui要素のIDを、第2引数には組み込み変数を指定します。
on init
make_perfview
set_ui_height(3)
declare ui_slider $Slider(0,100)
set_control_par_str(get_ui_id($Slider),$CONTROL_PAR_PICTURE,...
"pv_orchestral_knob")
end on
これはスライダーを宣言し、そこからスライダーの画像を変更しています。pv_orchestral_knobというのは、Kontakt4をインストールするとプリセットに組み込まれる画像データです。get_ui_idは、UI要素の名前を渡すとIDを返します。
on init
make_perfview
set_ui_height(1)
end on
on note
set_skin_offset($EVENT_NOTE)
end on
ノートナンバーの高低で、壁紙が動きます。
on init
declare ui_knob $Knob(0,100,1)
set_control_help($Knob,"Knob")
end on
ノブの上にマウスを持ってくると、インフォペインにKnobと表示されると思います。set_key_colorと同じように、こういうところにも配慮したいところですね:-)
on init
declare $count
end on
on note
set_key_color(60,$KEY_COLOR_YELLOW)
set_key_color(62,$KEY_COLOR_GREEN)
set_key_color(64,$KEY_COLOR_RED)
set_key_color(65,$KEY_COLOR_CYAN)
set_key_color(67,$KEY_COLOR_BLUE)
end on
on release
while ($count < 128)
set_key_color($count,$KEY_COLOR_WHITE)
$count := $count + 1
end while
$count := 0
end on
on init
set_script_title("Junk Guitar")
end on
on init
make_perfview
set_ui_height(8)
declare ui_knob $Knob(0,1000,1)
move_control($Knob,1,1)
declare $X := 1
declare $Y := 1
end on
on note
if($X < 6)
$X := $X + 1
else
$X := 1
if($Y < 15)
$Y := $Y + 2
else
$Y := 1
end if
end if
move_control($Knob,$X,$Y)
end on
このプログラムを実行すると、ノートオン毎にノブが動きます。ちなみにmove_control_pxは、ピクセル単位で動かすことが出来ます。
on init
make_perfview
set_ui_height(8)
declare ui_knob $Knob(0,1000,1)
move_control_px($Knob,66,2)
declare $X := 66
declare $Y := 2
end on
on note
if($X < 500)
$X := $X + 90
else
$X := 66
if($Y < 260)
$Y := $Y + 40
else
$Y := 2
end if
end if
move_control_px($Knob,$X,$Y)
end on
で、これはピクセル単位で動かしただけ。
on init
make_perfview
declare ui_knob $Knob(0,100,1)
end on
試しに、これをどこかのスロットに。
on init
make_perfview
declare ui_table %table_1[10] (2,2,100)
declare ui_table %table_2[10] (2,2,-100)
end on
これは別のスロットにコピペしてみてください。この状態で、パフォーマンスビューを確認してみると、効果が分かると思います。
on init
make_perfview
set_ui_height(8)
end on
こっちはグリッド単位。
on init
make_perfview
set_ui_height_px(350)
end on
こちらはピクセル単位。
n init
declare ui_waveform $Waveform(6,6)
end on
で、これだけだと、箱を用意しただけなので、表示する波形を指定しないといけません。attach_zoneで、第1引数にui_waveformの変数、第2引数にゾーンID、第3引数にフラグを指定します。ゾーンIDは、find_zoneにゾーンの名前を渡して、IDを返してもらいます。ちなみにfind_zoneはinit callbackでしか使えません。
on init
declare ui_waveform $Waveform(6,6)
attach_zone ($Waveform,find_zone(”Zone_1”),0)
end on
これで、Zone_1の波形が表示されます。ちなみにゾーン名は、「Browse」を有効にして、Monitorタブをクリック、Zonesのところに表示されてます。フラグについては、僕もはっきりと理解できていません。ご存じの方がいらっしゃいましたら、教えて頂ければ幸いです。
on init
declare ui_table %table_1[10] (2,2,100)
declare ui_table %table_2[10] (2,2,-100)
end on
set_table_steps_shownは、テーブルの列の数を変更する時に使います。第1引数に配列を、第2引数に変更したい値を指定します。
on init
declare ui_table %table_1[10] (2,2,100)
set_table_steps_shown(%table_1,5)
end on
ここで、気を付けないといけないのが、最初に配列で指定した以上の数には変更できないことです。
on init
declare ui_table %table_1[10] (2,2,100)
set_table_steps_shown(%table_1,20)
end on
列数を20に指定しても、変化しません。これは、配列 table_1が10までしか宣言していないからです。
on init
declare ui_menu $Menu
add_menu_item($Menu,"8th",0)
add_menu_item($Menu,"16th",1)
add_menu_item($Menu,"32th",2)
$Menu := 0
end on
実際に実行してみると、第2引数のテキストまでは、意味がわかると思います。第3引数ですが、$Menu := 0のところを、1とか2にしてみると意味が分かると思います。つまり、$Menuの値とテキストを対応付けているわけです。ということは、以下のように書いても問題ないわけです。
on init
declare ui_menu $Menu
add_menu_item($Menu,"8th",2)
add_menu_item($Menu,"16th",1)
add_menu_item($Menu,"32th",0)
$Menu := 0
end on
on init
declare ui_knob $Knob (0,100,1)
hide_part($Knob,$HIDE_PART_BG...
.or. $HIDE_PART_MOD_LIGHT...
.or. $HIDE_PART_TITLE...
.or. $HIDE_PART_VALUE)
end on
で、こんなことが出来て何が嬉しいのかと言いますと、Kontaktでは、Instrument Optionsで、壁紙を設定出来るわけです。（フォントとかで）グラフィックデザインにこだわりたい場合には、これで各要素のパーツを隠して、壁紙の方でテキストとかを配置することも出来るわけなんですねー。（僕はグラフィックデザインは出来ないので、一人ではそこまで作り込めませんが……）
on init
declare ui_value_edit $Value (0,100,1)
end on
on init
declare ui_label $Label_1 (1,4)
end on
とりあえず、ラベルを表示しただけです。set_textは第1引数には変数、第2引数にはテキストを指定するだけです。set_textはこんな感じになります。
on init
declare ui_label $Label_1 (1,4)
set_text($Label_1,"Label")
declare ui_knob $Knob_1 (0,100,1)
set_text($Knob_1,"Knob")
declare ui_button $Button_1
set_text($Button_1,"Button")
declare ui_switch $Switch_1
set_text($Switch_1,"Switch")
declare ui_value_edit $Value_Edit (0,100,1)
set_text($Value_Edit,"Value_Edit")
end on
これも特に難しくないですよね。ui_value_editは次回以降に説明しますが、実際に実行してみれば引数の動作はui_knobと一緒なのが分かると思います。add_text_lineは、テキストをどんどん追加していきますが、set_textは、既存のテキストを一度全部消去してしまいます。
on init
declare ui_label $Label_1 (1,4)
set_text($Label_1,"Label")
add_text_line($Label_1,"Test")
end on
on note
add_text_line($Label_1,$EVENT_NOTE)
end on
on controller
if($CC_NUM = 1)
set_text($Label_1,"Clear")
end if
end on
ノートオンのたびに、ノートナンバーがラベルにどんどん追加されると思います。そして、モジュレーションホイールを動かすと、全てのテキストが消去され、「Clear」の文字だけになるはずです。set_textとadd_text_lineの違いはこんなところです。
on init
declare ui_button $Button_1
declare ui_switch $Switch_1
end on
とりあえず、ボタンとスイッチを表示しただけ。
on init
declare ui_button $Button_1
declare ui_button $Button_2
declare ui_button $Button_3
$Button_1 := 1
end on
on ui_control ($Button_1)
if($Button_1 = 0)
$Button_1 := 1
else
$Button_2 := 0
$Button_3 := 0
end if
end on
on ui_control ($Button_2)
if($Button_2 = 0)
$Button_2 := 1
else
$Button_1 := 0
$Button_3 := 0
end if
end on
on ui_control ($Button_3)
if($Button_3 = 0)
$Button_3 := 1
else
$Button_1 := 0
$Button_2 := 0
end if
end on
ボタンをラジオボタンみたいな挙動にしてみました。
on init
declare ui_slider $Slider (0,100)
end on
on ui_control($Slider)
message($Slider)
end on
on init
declare ui_knob $Knob_1(0,100,1)
set_knob_unit($Knob_1,$KNOB_UNIT_NONE)
declare ui_knob $Knob_2(-600,600,100)
set_knob_unit($Knob_2,$KNOB_UNIT_DB)
declare ui_knob $Knob_3(4300,4500,10)
set_knob_unit($Knob_3,$KNOB_UNIT_HZ)
declare ui_knob $Knob_4(0,100,1)
set_knob_unit($Knob_4,$KNOB_UNIT_PERCENT)
declare ui_knob $Knob_5(0,1000,10)
set_knob_unit($Knob_5,$KNOB_UNIT_MS)
declare ui_knob $Knob_6(-4,4,1)
set_knob_unit($Knob_6,$KNOB_UNIT_OCT)
declare ui_knob $Knob_7(0,100,1)
set_knob_unit($Knob_7,$KNOB_UNIT_ST)
end on
on init
declare ui_knob $Rate (0,17,1)
set_knob_label($Rate,"Text")
end on
で、このように書いちゃうと、ノブをいくら回してもTextとしか表示されません。なので、この場合は、先に文字列配列を用意します。そして、ノブを回した時に文字列配列からテキストを読み込むようにします。
on init
declare !rate_names[18]
!rate_names[0] := "1/128"
!rate_names[1] := "1/64"
!rate_names[2] := "1/32"
!rate_names[3] := "1/16 T"
!rate_names[4] := "3/64"
!rate_names[5] := "1/16"
!rate_names[6] := "1/8 T"
!rate_names[7] := "3/32"
!rate_names[8] := "1/8"
!rate_names[9] := "1/4 T"
!rate_names[10] := "3/16"
!rate_names[11] := "1/4"
!rate_names[12] := "1/2 T"
!rate_names[13] := "3/8"
!rate_names[14] := "1/2"
!rate_names[15] := "3/4"
!rate_names[16] := "4/4"
!rate_names[17] := "Bar"
declare ui_knob $Rate (0,17,1)
$Rate := 8
set_knob_label($Rate,!rate_names[$Rate])
end on
on ui_control ($Rate)
set_knob_label($Rate,!rate_names[$Rate])
end on
文字列配列rate_namesにそれぞれテキストを入れてます。その後に、ui_knobの初期値8(1/8)を指定して、ノブのラベルにテキストを設定しています。あとは、ui callbakにて、ノブの値が変更される度に、テキストも変更するようにしています。
on init
declare ui_knob $Knob(-100,100,1)
set_knob_defval ($Knob,0)
end on
このプログラムを実行するとわかりますが、スクリプトを読み込んだ時には、Knobの値は0ではなく-100になります。スクリプトの解析が終わった段階で、Knobの値を0にしたい場合は以下のようにします。あ、その前に、一応、コマンドキーを押しながらノブをクリックして、動作を確認しておいてくださいね（笑）。
on init
declare ui_knob $Knob(-100,100,1)
set_knob_defval ($Knob,0)
$Knob := 0
end on
on init
declare ui_knob $Knob_1 (0,10,1)
declare ui_knob $Knob_2 (0,100,1)
declare ui_knob $Knob_3 (0,1000,1)
declare ui_knob $Knob_4 (5,10,1)
declare ui_knob $Knob_5 (500,1000,1)
end on
さて、どれも特に理解するのに難しくない動作をすると思います。ちなみに、マウスで数値を細かく調整したい時にはshiftキーを押しながらになります。では、次のコードを見てください。
on init
declare ui_knob $Knob_1 (0,1000,1)
declare ui_knob $Knob_2 (0,1000,10)
declare ui_knob $Knob_3 (0,1000,100)
declare ui_knob $Knob_4 (0,1000,20)
declare ui_knob $Knob_5 (0,1000,-1)
declare ui_knob $Knob_6 (0,1000,-10)
end on
Knob_1は、特に難しくないですよね。では、Knob_2の動作です。これは結果的に、最小値が0で、最大値が100、単位が0.1ずつになると思います。Knob_1との違いは、display-ratioの値だけですので、ここが怪しいとなります。で、どういうことかというと、display-ratioを10にすると、第2引数に指定した値を10で割った値が最大値になります。この場合は、1000を10で割ると100になりますので、最大値は100になるわけです。さらに、ノブを動かした時の数値の変化の単位も1を10で割った値になります。つまり0.1ずつの変化になるわけです。同じようにKnob_3もKnob_4も計算してみてください。どうですか？ちゃんと計算したとおりの動作を確認できたでしょうか？ちなみにKnob_5とKnob_6は、マイナスを付けただけです。
on init
declare ui_knob $Knob_1 (500,1000,10)
end on
ちなみに、第1引数に0以外の数値を指定した場合も、display-ratioで指定した値で割った値になります。この場合は、最小値が50.0で、最大値が100.0で、単位が0.1ずつの変化になります。
on init
declare ui_knob $Knob (0,100,1)
end on
on ui_control ($Knob)
message("Knob" & "(" & $ENGINE_UPTIME & ")")
end on
ui_knobについては、次回以降に説明しますので割愛します（まぁ、プログラムを実行すれば一目瞭然ですがｗ）。ここで大事なのは、ui_control($Knob)の部分です。これは変数Knobに何らかの変化があると実行されるという意味です。ちなみに$ENGINE_UPTIMEとは、Kontaktが起動してからの経過時間をミリ秒単位で返します。つまり、ノブを動かすと経過時間がステータスラインに表示されるというわけです。簡単ですが、まずはここを理解しておいてください。
on init
declare $count := 0
declare ui_menu $groups_menu
while ($count < $NUM_GROUPS)
add_menu_item ($groups_menu,group_name($count),$count)
inc($count)
end while
end on
$NUM_GROUPSは、グループの総数です。add_menu_itemで、メニューにグループ名を一つ一つセットしているわけです。
on init
declare ui_button $Purge
set_text ($Purge,"Purge First Group")
end on
on ui_control ($Purge)
message($Purge)
purge_group(0 ,abs($Purge-1))
end on
ボタンをクリックすると、インデックス0のグループがパージされます。ボタンは、押した状態が1で、押されていない状態が0になるのがわかるように、message($Purge)で表示しています。つまり、押されていない状態の変数Purgeの状態が0なわけですから、-1をして、abs()で絶対値をとると1になるわけです。つまり、ボタンをクリックする度に、パージされたり、リロードされたりするわけです。ちなみに、グループ名を使いたい時には、以下のようになります。
on init
declare ui_button $Purge
set_text ($Purge,"Purge Single")
end on
on ui_control ($Purge)
message($Purge)
purge_group(finde_group("Single") ,abs($Purge-1))
end on
get_purge_stateは、第1引数にグループインデックスを渡します。パージされていれば0が、されていなければ1を返します。
on init
declare $State
declare ui_button $Purge
set_text ($Purge,"Purge First Group")
end on
on ui_control ($Purge)
purge_group(0 ,abs($Purge-1))
$State := get_purge_state(0)
message($State)
end on
on init
declare $Flag := 0
end on
on note
inc($Flag)
message($Flag)
if($Flag > 1)
disallow_group($ALL_GROUPS)
allow_group(find_group("Hammer"))
else
disallow_group($ALL_GROUPS)
allow_group(find_group("Single"))
end if
end on
on release
dec($Flag)
message($Flag)
end on
仮に、SingleとHammerという２つのグループが存在するライブラリがあったとします（この２つのグループには、特にキースイッチなどの設定はしない）。そこで、このスクリプトを適用すると、単音でレガートに弾くとHammerが発音されます。（ただし、実際にこのままスクリプトを使うと、色々とバグが発生しますので、オススメしません）。この、disallow_groupとallow_groupで気を付けないといけないのが、そのコールバックを呼んだイベントにしか適用されないということです。つまり、いわゆるキースイッチみたいな使い方は出来ないということです。例として、以下のスクリプトを見てください。
on note
message($EVENT_NOTE)
select($EVENT_NOTE)
case 12
disallow_group($ALL_GROUPS)
allow_group(find_group("Group_1"))
case 13
disallow_group($ALL_GROUPS)
allow_group(find_group("Group_2"))
case 14
disallow_group($ALL_GROUPS)
allow_group(find_group("Group_3"))
case 15
disallow_group($ALL_GROUPS)
allow_group(find_group("Group_4"))
end select
end on
この場合、一見して、キースイッチのように動作するように思えます。しかし、ノートナンバー12のノート・オン・イベントが発生しても、それ自身のイベントにのみ有効であるため、ノートナンバー12のノート・オンでしか、Group_1にマッピングされたサウンドは再生されません。
on init
declare %Array [10] := (0,1,2,3,4,5,6,7,8,9)
declare ui_menu $Menu
add_menu_item($Menu,"Save",0)
add_menu_item($Menu,"Load",1)
declare ui_table %Table[10](3,3,10)
declare $i
end on
on ui_control ($Menu)
select($Menu)
case 0
$i := 0
while($i < 10)
%Array[$i] := %Table[$i]
$i := $i + 1
end while
save_array(%Array,0)
case 1
load_array(%Array,0)
$i := 0
while($i < 10)
%Table[$i] := %Array[$i]
$i := $i + 1
end while
end select
end on
メニューにて、Saveを選択した時には、テーブルの値を配列Arrayにコピーした後、ファイルに保存するダイアログが表示されます。Loadを選択した時には、ダイアログが表示され、ファイルを選択し、配列Arrayeに値が読み込まれ、テーブルの値にコピーします。テーブルを適当にクリックして、値を変更したら、メニューでSaveを選んで、適当な名前を付けて、デスクトップに保存してください。そのファイルをテキストエディタで開くと、どのようなファイルになっているか分かります。
on init
declare ui_table %Table[10] (3,3,100)
end on
on note
sort(%Table,0)
end on
ui_tableについては後日説明します。とりあえず、Kontaktの画面に表示されるテーブルの値を適当に変更してみてください。その後、ノートオンで、小さい順に並べ替えされます。
on init
declare %Array_1[10] := (0,1,2,3,4,5,6,7,8,1)
declare $Number
end on
on note
if(search(%Array_1,1) = -1)
message("Not Found")
else
$Number := search(%Array_1,1)
message($Number)
end if
end on
on release
message(" ")
end on
このプログラムでは、ステータスラインに1が表示されます。Array_1[9]の1は無視されます。ついでに、以下のコードも記載しておきます。
on init
declare %Array_1[10] := (0,1,2,3,4,5,6,7,8,1)
declare $Number
end on
on note
if(search(%Array_1,9) = -1)
message("Not Found")
else
$Number := search(%Array_1,1)
message($Number)
end if
end on
on release
message(" ")
end on
この場合は、Not Foundのテキストがステータスラインに表示されます。
on init
declare %Array_1[10] := (0,1,2,3,4,5,6,7,8,9)
declare %Array_2[20] := (0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19)
declare $Number
end on
on note
if($EVENT_NOTE > 64)
$Number := num_elements(%Array_1)
message($Number)
else
$Number := num_elements(%Array_2)
message($Number)
end if
end on
on release
message(" ")
end on
ノートナンバーが64以上で配列Array_1の要素数が、ノートナンバーが63以下で配列Array_2の要素数がステータスラインに表示されます。
on init
declare %Array_1[10]
declare %Array_2[20]
if(array_equal(%Array_1, %Array_2))
message("Array_1 = Array_2")
end if
end on
このプログラムはエラーが出ます。なぜなら、比較対象の配列Array_1とArray_2のサイズが違うからです。比較する場合には、同じサイズである必要があります。では、次のコードを見てください。
on init
declare %Array_1[10] := (0,1,2,3,4,5,6,7,8,9)
declare %Array_2[10] := (0,1,2,3,4,5,6,7,8,9)
end on
on note
if(array_equal(%Array_1, %Array_2))
message("Array_1 = Array_2")
end if
end on
on release
message(" ")
end on
このプログラムでは、ノートオンで、「Array_1 = Array_2」のテキストがステータスラインに表示されます。では、さらに次のコードを見てください。
on init
declare %Array_1[10] := (0,1,2,3,4,5,6,7,8,9)
declare %Array_2[10] := (0,1,2,3,4,5,6,7,8,10)
end on
on note
if(array_equal(%Array_1, %Array_2))
message("Array_1 = Array_2")
else
message("Array_1 # Array_2")
end if
end on
on release
message(" ")
end on
このプログラムでは、ノートオンで、「Array_1 # Array_2」のテキストがステータスラインに表示されます。つまり、１つでも配列の中の値が違えば、falseが返ってくるわけです。
| x .and. y | ビット単位のand |
| x .or. y | ビット単位のor |
| .not. x | ビット単位の否定 |
| sh_left( |
ビット単位での左シフト |
| sh_right( |
ビット単位での右シフト |
on init
declare $X := 162
declare $Y := 10
declare $A
end on
on note
$A := $X .and. $Y
message($A)
end on
ビット単位のorとは、少なくともどちらかが1であれば1を返します。170と、85のビット単位のorとは、2進数にすると1010 1010と0101 0101のビット単位のorということなので、1111 1111の255になります。
on init
declare $X := 170
declare $Y := 85
declare $A
end on
on note
$A := $X .or. $Y
message($A)
end on
ビット単位のnotとは、つまり、ビット単位で反転するわけですね。170をビット単位でnot演算すると、1010 1010が0101 0101になるので、85に……なりません（笑）。まずは、以下のコードを見てください。
on init
declare $X := 170
declare $A
end on
on note
$A := .not. $X
message($A)
end on
このプログラムを実行すると、ステータスラインには、-171と表示されます。なぜでしょうか？まず、2進数で一番左の桁というのは、1で負の値、0で正の値を意味します。つまり、170を2進数で表すと、一番左の桁は0なのです。この0は.not.で1になりますから、符号が-に変わるわけです。コンピュータ内では、正の値の最大値は一番左の桁が0で、残りの桁が全て1の数です。負の値の最小値は、一番左の桁が1で、残りの桁が全て0の数です（-1は、2進数にすると全ての桁が1になります）。そして、もう1つ、2の補数という概念を理解しないといけません。2の補数とは、ビット単位で全て反転させて、+1をした数です。この辺りの理屈を理解するには、「2の補数」でググッて調べてみてください。
では、次にいきましょう。
on init
declare $X := 170
declare $A
end on
on note
$A := sh_left($X,2)
message($A)
end on
左シフトとは、ビット単位で、指定した単位だけ、桁を左にずらします。桁を１つずらせば、数は2倍、2つずらせば4倍、3つずらせば8倍となっていきます。このプログラムの場合は4倍になるので、680がステータスラインに表示されます。逆に右シフトの場合は、1/2、1/4、1/8となっていくわけです。今回は、2進数が理解できていないと、なかなか難しいと思いますので、興味のない方は、全く理解できなくても問題ありません。これでKSPの演算子については終わりです。
| x > y | xはyより大きい |
| x < y | xはyより小さい |
| x >= y | xはyより大きいか等しい |
| x <= y | xはyより小さいか等しい |
| x = y | xとyは等しい |
| x # y | xとyは等しくない |
| in_range(x,y,z) | xは、yとzの間の値である |
| not a | aが偽であった場合に真を返し、aが真であった場合に偽を返す |
| a and b | aもbもどちらも真である |
| a or b | aかbのどちらかが真である |
on init
declare $X := 1
declare $Y := 1
declare $Z := 1
end on
on note
if($X = $Y and $Y = $Z)
message("X = Y = Z")
end if
end on
この場合は、表の「a and b」を使っていますね。変数Xと変数Yが等しく、かつ、変数Yと変数Zも等しい場合に、ステータスラインに文字列が表示されます。
while(条件)
{プログラム}
end while
もう、見慣れましたよね。では、早速、例を見ていきましょう。（あ、ちなみに、このプログラムを実行してはいけません。あとで説明します）
on init
declare $Flag := 1
end on
on note
while($Flag = 1)
play_note($EVENT_NOTE,$EVENT_VELOCITY,0,$DURATION_QUARTER/2)
wait($DURATION_QUARTER)
end while
end on
play_noteというのは、()内で指定した条件を元に、ノートオンを生成します。余談ですが、この()内のそれぞれの値を引数（ひきすう）と言ったりします。play_noteを関数とか言ったりもします。まぁ、関数は、命令の事だと思ってもらっていいです。「ここで、この命令を実行してくれ」とKontaktに伝えるわけです。で、その命令に細かく指示を出すために、引数が必要になったりするわけですね。この関数と引数のセットは、予め使い方が決まっています（関数は他にもたくさんあるので、後日、少しずつ説明します）。
on note
while($NOTE_HELD = 1)
play_note($EVENT_NOTE,$EVENT_VELOCITY,0,$DURATION_QUARTER/2)
wait($DURATION_QUARTER)
end while
end on
$NOTE_HELDというのは、要は鍵盤を押しっぱなしかどうか？という状態を保持している変数です。押しっぱなしであれば値が１で、そうでなければ0になります。これで、プログラムは暴走しなくなったわけです。
select(比較に使いたい変数）
case (条件）
{実行するプログラム}
case (条件）
{実行するプログラム}
case (条件）
{実行するプログラム}
end select
このように、select(変数)で、条件分岐に使いたい変数を指定します。 case (条件)で、その変数の値がいくつの時にプログラムを実行したいかを指定します。では、ノートナンバー64,65,66にそれぞれキースイッチが設定されていると仮定して、それぞれのキースイッチが押された時に、どのグループが指定されたのかを、文字列でステータスラインに表示するプログラムを書いてみましょう。ちなみにノートナンバー64とは、Eの音です。
on note
select($EVENT_NOTE)
case(64)
message("Single")
case(65)
message("Mute")
case(66)
message("Picking Harmonics")
end select
end on
実際には、キースイッチを押されたときの動作を指定したい場合に、ステータスラインに文字を表示するだけということはないと思います。（もっとカッコイイ動作を作りこみたいですよねw）でも、少しずつですが、KSPを使ったライブラリのイメージが出来そうな雰囲気になってきましたね！
if(ここの条件を記述)
{条件に合致した場合実行するプログラム}
end if
というように、if(条件)から始まりend ifで終わります。
では、以下のコードを見てください。
on init
declare $Check
$Check := 1
end on
on note
if ($Check = 1)
message($EVENT_NOTE)
end if
end on
「if($Check = 1)」は、もし変数Checkの値が1なら、という意味です。init callbackで、変数Checkに値1を代入しているので、もちろん、この条件を満たしているわけです。あとはいつものようにステータスラインにノートナンバーを表示しているだけです。
では、次のコードを見てください。
on note
if($EVENT_NOTE > 64)
message("Note Number is " & $EVENT_NOTE)
else
message($EVENT_NOTE)
end if
end on
新しく「else」というのが登場しています。elseというのは、if文の条件に合致しなかった場合に実行される動作を指定します。つまり、ノートナンバーが64より大きければ「Note Number is ノートナンバー」がステータスラインに表示され、ノートナンバーが64より大きくなかった場合には、ノートナンバーだけがステータスラインに表示されます。
他のプログラミング言語だと、もう少し複雑な制御をif文で出来るのですが、 Kontaktの場合はこれだけです。実際にKSPでプログラミングをする時には、if文はよく使いますので、がんばってしっかりと覚えてください。
on init
declare @text
@text := "Note Number"
end on
on note
message(@text & $EVENT_NOTE)
end on
on release
message(@text & $EVENT_NOTE)
end on
文字列変数textを宣言して、文字列"Note Number"を代入しています。あとは、ノート・オン時にノートナンバーをステータスラインに表示します。$EVENT_NOTEとは、組み込み変数の1つです。組み込み変数とは、予めKSPに定義された変数のことで、全て大文字になります。$EVENT_NOTEは、callbackを起動したイベントのノートナンバーが格納されます。
文字列配列は、「declare !text[2]」のように、配列のサイズを指定して宣言しなければなりません。以下のコードを見てください。
on init
declare !text[2]
!text[0] := "Note Number"
!text[1] := "Release Note Number"
end on
on note
message(!text[0] & $EVENT_NOTE)
end on
on release
message(!text[1] & $EVENT_NOTE)
end on
前回の配列の記事を読んでいる人は、特に解説しなくても、何をやっているかわかると思います:-)
これで、KSPに用意されている変数の機能（組み込み変数は除く）は、全て理解出来たことになります。お疲れ様でした！
on init
declare %Array[10] := (...
1,2,3,4,5,6,7,8,9)
end on
on note
message(%Array[0])
end on
int型の配列%Arrayをサイズ10でして宣言し、配列の宣言と同時に、配列の値も代入しています。ノートオン時には、ステータスラインに配列の1番目の値を表示します。ここで「おや？」と思った人もいるのではないでしょうか。プログラミングでは日常的なことなのですが、配列の1番目は0から数えます。10番目の値を表示したい時には、「message(%Array[9])」となるわけです。
また、配列は以下のように、取り出して使うことも出来ます。
on init
declare %Array[10] := (...
0,1,2,3,4, 5,6,7,8,9)
declare $Int
end on
on note
$Int := %Array[9]
message($Int)
end on
配列Arrayの10番目の値を、int型の変数Intに代入して、ステータスラインに表示します。ちなみに、2行目の「...」はプログラムを途中で改行した時に記述します。つまり、本来は「declare %Array[10] := (0,1,2,3,4, 5,6,7,8,9)」と1行で記述するところを、「...」を使って少し見やすく出来るわけです。
配列に値を代入したい時には、以下のように記述します。
on init
declare %Array[10] := (...
0,1,2,3,4, 5,6,7,8,9)
declare $Int
end on
on note
%Array[9] := 21
message(%Array[9])
end on
「%Array[9] := 21」で、配列Arrayの10番目に21を代入して、ステータスラインに表示します。
これで、配列の基本的な使い方は理解できたと思います:-)
on init
declare const $Constant
$Constant := 16
end on
on init
declare const $Constant := 16
end on
on init
declare const $Constant := 16
end on
on note
$Constant := 32
end on
on init
declare polyphonic $a
end on
on note
$a := 4
message($a)
wait(1000000)
$a := $a + 4
message($a)
wait(1000000)
$a := $a + 4
message($a)
wait(1000000)
$a := $a + 4
message($a)
wait(1000000)
$a := $a + 4
message($a)
wait(1000000)
$a := $a + 4
message($a)
wait(1000000)
$a := $a + 4
message($a)
end on
on init
declare polyphonic $a
declare const $Constant := 4
end on
on note
$a := $Constant
message($a)
wait(1000000)
$a := $a + $Constant
message($a)
wait(1000000)
$a := $a + $Constant
message($a)
wait(1000000)
$a := $a + $Constant
message($a)
wait(1000000)
$a := $a + $Constant
message($a)
wait(1000000)
$a := $a + $Constant
message($a)
wait(1000000)
$a := $a + $Constant
message($a)
end on
on init
declare $Poly
$Poly := 0
end on
on note
$Poly := $Poly + 1
message($Poly)
end on
on release
$Poly := $Poly - 1
message($Poly)
end on
on init
declare polyphonic $Poly
$Poly := 0
end on
on note
$Poly := $Poly + 1
message($Poly)
end on
on release
$Poly := $Poly - 1
message($Poly)
end on
on init
declare $Instrument
end on
on init
declare $Instrument
end on
on note
$Instrument := 1024
message("No." & $Instrument & "!")
end on
on init
{ここに実行させたいプログラムを記述します}
end on